<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:cs="http://namespaces.zope.org/clearsilver"
    version="1.0" >
  <xsl:output method="xml" /> 

  <xsl:template match="/">
    <xsl:apply-templates />
  </xsl:template>

  <xsl:template match="*[@cs:content]">
    <xsl:copy>
      <xsl:apply-templates select="@*" />
    </xsl:copy>
   </xsl:template>

  <xsl:template match="*[@cs:replace]">
    <xsl:apply-templates select="@*[namespace-uri()='http://namespaces.zope.org/clearsilver']" />
  </xsl:template>
  
  <xsl:template match="@cs:define">
    <xsl:processing-instruction name="cs">set:<xsl:value-of select="." /></xsl:processing-instruction>
  </xsl:template>

  <xsl:template match="@cs:content | @cs:replace">
    <xsl:choose>
      <xsl:when test="starts-with(., 'structure ')">
	<xsl:processing-instruction name="cs">var:<xsl:value-of select="substring(., 11)" /></xsl:processing-instruction>
      </xsl:when>
      <xsl:otherwise>
	<xsl:processing-instruction name="cs">var:html_escape(<xsl:value-of select="." />)</xsl:processing-instruction>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="@cs:attributes">
    <xsl:call-template name="attribute">
      <xsl:with-param name="attr" select="."/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="attribute">
    <xsl:param name="attr"/>
    <xsl:choose>
      <xsl:when test="contains($attr,';')">
	<xsl:call-template name="attribute">
	  <xsl:with-param name="attr" select="substring-after($attr,'; ')"/>
	</xsl:call-template>
	<xsl:call-template name="output_attribute">
	  <xsl:with-param name="segment" select="substring-before($attr, '; ')" />
	</xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
	<xsl:call-template name="output_attribute">
	  <xsl:with-param name="segment" select="$attr"/>
	</xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template name="output_attribute">
    <xsl:param name="segment"/>
    <xsl:variable name="name" select="substring-before($segment, ' ')"/>
    <xsl:variable name="value" select="substring-after($segment, ' ')"/>
    <xsl:attribute name="{$name}">
      <xsl:text disable-output-escaping="yes">&lt;?cs var:html_escape</xsl:text>(<xsl:value-of disable-output-escaping="yes" select="$value"/>)<xsl:text disable-output-escaping="yes">?&gt;</xsl:text>
    </xsl:attribute>    
  </xsl:template>
  
  <xsl:template match="@*">
    <xsl:if test="namespace-uri() != 'http://namespaces.zope.org/clearsilver'">
      <xsl:copy-of select="."/>
    </xsl:if>
  </xsl:template>
  
  <xsl:template match="*">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates />
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="comment()">
    <xsl:comment><xsl:value-of select="."/></xsl:comment>
  </xsl:template>

</xsl:stylesheet>